pxJCreateFixed%(body1%, body2%)

Параметры

body1%, body2% - соединяемые тела

Описание

Создаёт фиксированное сочление. Можно использовать для фиксации объектов относительно друг друга.
Внимание - соединение не создается между статическим (с массой 0) и динамическим телами.
Для того чтоб получить шарнир, привязанный к статике, нужно вместо body1 указать 0.

Смотрите так же

Пример

;Пример применения функции
;pxJCreateFixed

Graphics3D 800, 600, 32, 2
SetBuffer BackBuffer()

;Создаем физический мир, устанавливаем гравитацию.
pxCreateWorld(1) ;У нас будет поверхность
pxSetGravity(0, -10, 0)

camera=CreateCamera()
light=CreateLight()

PositionEntity camera,0,20,-40
RotateEntity camera,30,0,0

plane=CreatePlane() ;Визуализируем поверхность
EntityColor plane,0,100,200
EntityAlpha plane,0.5

mir = CreateMirror () ;Чуть украсим зеркалом

body1 = pxCreateCube( 1, 1, 1, 20)
pxSetPosition(body1,0,3,0)
mesh1 = CreateCube()
EntityColor mesh1,255,0,0 ;цвет - красный

body2 = pxCreateCube( 1, 1, 1, 20)
pxSetPosition(body2,0,9,0)
mesh2 = CreateCube()
EntityColor mesh2,0,255,0 ;цвет - зеленый

; ------------ Применяем pxJCreateFixed
;Создаем фиксированое соединение
pxJCreateFixed(body1, body2)

;Основной цикл программы
While Not KeyDown(1) ;Пока не нажат ESC

    RenderPhysic(60,0)

;Применяем силы в зависимости от нажатой клавиши
    If KeyDown(200) pxAddForce(body2,0,0,2000,0)
    If KeyDown(208) pxAddForce(body2,0,0,-2000,0)
    If KeyDown(205) pxAddForce(body2,2000,0,0,0)
    If KeyDown(203) pxAddForce(body2,-2000,0,0,0)

;Обновим положения объектов
    pxSetEntity(mesh1,body1)
    pxSetEntity(mesh2,body2)

    RenderWorld
    Text 10,10, "Стрелки курсора - добавить силу к зеленому телу"
    Flip
    Wend

End

К содержанию

Нажмите здесь чтобы увидеть последнюю версию этой странички в режиме online.